tfc/src/shared/w_pipebomb.qc

/*
 * Copyright (c) 2016-2020 Marco Cawthorne <marco@icculus.org>
 *
 * Permission to use, copy, modify, and distribute this software for any
 * purpose with or without fee is hereby granted, provided that the above
 * copyright notice and this permission notice appear in all copies.
 *
 * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
 * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
 * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
 * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
 * WHATSOEVER RESULTING FROM LOSS OF MIND, USE, DATA OR PROFITS, WHETHER
 * IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING
 * OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
 */

void
w_pipebomb_precache(void)
{
#ifdef SERVER
	Sound_Precache("weapon_handgrenade.bounce");
	Sound_Precache("weapon_mp5.gl");
	precache_model("models/w_pipebomb.mdl");
	precache_model("models/p_pipebomb.mdl");
	precache_model("models/pipebomb.mdl");
#else
	precache_model("models/v_tfgl.mdl");
#endif
}

void
w_pipebomb_updateammo(player pl)
{
	Weapons_UpdateAmmo(pl, pl.mag_pipebomb, pl.m_iAmmoRockets, __NULL__);
}

int
w_pipebomb_pickup(player pl, int new, int startammo)
{
#ifdef SERVER
	pl.mag_pipebomb = bound(0, pl.mag_pipebomb + 6, 6);
#endif
	return (1);
}

string
w_pipebomb_wmodel(void)
{
	return "models/w_pipebomb.mdl";
}
string
w_pipebomb_pmodel(player pl)
{
	return "models/p_pipebomb.mdl";
}

string
w_pipebomb_deathmsg(void)
{
	return "%s was assaulted by %s's Assault Cannon.";
}

void
w_pipebomb_draw(player pl)
{
	Weapons_SetModel("models/v_tfgl.mdl");
	Weapons_ViewAnimation(pl, GLAUNCHER_PDRAW);
}

void
w_pipebomb_shootnade(player pl)
{
	vector vecNadeVelocity;

	static void w_pipebomb_shootnade_touch(void) {
		Sound_Play(self, CHAN_BODY, "weapon_handgrenade.bounce");

		if (vlen(self.velocity))
			self.avelocity = g_vec_null;
	}

	Weapons_MakeVectors(pl);
	vecNadeVelocity = v_forward * 600 + v_up * 200 + crandom() * v_right * 10 + crandom() * v_up * 10;

	NSRenderableEntity eNade = spawn(NSRenderableEntity);
	eNade.SetModel("models/pipebomb.mdl");
	eNade.SetOrigin(Weapons_GetCameraPos(pl) + (v_forward * 14) + (v_up * -4) + (v_right * 2));
	eNade.SetOwner(pl);
	eNade.SetMovetype(MOVETYPE_BOUNCE);
	eNade.SetSolid(SOLID_BBOX);
	eNade.SetGravity(1.0f);
	eNade.SetVelocity(vecNadeVelocity);
	eNade.SetAngularVelocity([300, 300, 300]);
	eNade.SetAngles(vectoangles(eNade.GetVelocity()));
	eNade.SetSkin(0);

	eNade.touch = w_pipebomb_shootnade_touch;
	
	Sound_Play(pl, CHAN_WEAPON, "weapon_mp5.gl");

	//eNade.traileffectnum = particleeffectnum("weapon_rpg.trail");
}

void
w_pipebomb_reload(player pl)
{
	w_baseshotgun_reload(player::mag_pipebomb, player::m_iAmmoRockets, 6);
}

void
w_pipebomb_release(player pl)
{
	int s = w_baseshotgun_release(player::mag_pipebomb, player::m_iAmmoRockets, 6);

	switch (s) {
	case SHOTGUN_IDLE:
		Weapons_ViewAnimation(pl, GLAUNCHER_PIDLE);
		pl.w_idle_next = 5.0f;
		break;
	case SHOTGUN_BUSY:
		break;
	case SHOTGUN_START_RELOAD:
		Weapons_ViewAnimation(pl, GLAUNCHER_PRELOAD1);
		break;
	case SHOTGUN_RELOAD:
		break;
	case SHOTGUN_END_RELOAD:
		Weapons_ViewAnimation(pl, GLAUNCHER_PRELOAD2);
		break;
	}
}

void
w_pipebomb_primary(player pl)
{
	int s = w_baseprojectile_fire(pl, WEAPON_PIPEBOMB, player::mag_pipebomb, w_pipebomb_shootnade);

	switch (s) {
	case AUTO_FIRE_FAILED:
		w_pipebomb_release(pl);
		return;
		break;
	case AUTO_FIRED:
	case AUTO_LAST:
		Weapons_ViewAnimation(pl, GLAUNCHER_PFIRE);
		Weapons_ViewPunchAngle(pl, [-1,0,0]);
		pl.w_attack_next = 0.6f;
		break;
	case AUTO_EMPTY:
		Weapons_ViewAnimation(pl, GLAUNCHER_PIDLE);
		pl.w_attack_next = 0.2f;
		break;
	}

	pl.w_idle_next = 0.6f;
}

void
w_pipebomb_postdraw(player pl)
{
#ifdef CLIENT
	vector aicon_pos;

	/* ammo counters */
	HUD_DrawAmmo1();
	HUD_DrawAmmo2();

	/* ammo icon */
	aicon_pos = g_hudmins + [g_hudres[0] - 48, g_hudres[1] - 42];
	drawsubpic(
		aicon_pos,
		[24,24],
		"sprites/640hud7.spr_0.tga",
		[120/256,72/128],
		[24/256, 24/128],
		g_hud_color,
		pSeatLocal->m_flAmmo2Alpha,
		DRAWFLAG_ADDITIVE
	);
#endif
}

float
w_pipebomb_aimanim(player pl)
{
	return self.flags & FL_CROUCHING ? ANIM_CR_AIMCROWBAR : ANIM_AIMCROWBAR;
}

void
w_pipebomb_hudpic(player pl, int selected, vector pos, float a)
{
#ifdef CLIENT
	if (selected) {
		drawsubpic(
			pos,
			[170,45],
			"sprites/tfchud02.spr_0.tga",
			[0,90/256],
			[170/256,45/256],
			g_hud_color,
			a,
			DRAWFLAG_ADDITIVE
		);
	} else {
		drawsubpic(
			pos,
			[170,45],
			"sprites/tfchud01.spr_0.tga",
			[0,90/256],
			[170/256,45/256],
			g_hud_color,
			a,
			DRAWFLAG_ADDITIVE
		);
	}
#endif
}

weapon_t w_pipebomb =
{
	.name		= "pipebomb",
	.id		= ITEM_PIPEBOMB,
	.slot		= 4,
	.slot_pos	= 1,
	.draw		= w_pipebomb_draw,
	.holster	= __NULL__,
	.primary	= w_pipebomb_primary,
	.secondary	= __NULL__,
	.reload		= w_pipebomb_reload,
	.release	= w_pipebomb_release,
	.postdraw	= w_pipebomb_postdraw,
	.precache	= w_pipebomb_precache,
	.pickup		= w_pipebomb_pickup,
	.updateammo	= w_pipebomb_updateammo,
	.wmodel		= w_pipebomb_wmodel,
	.pmodel		= w_pipebomb_pmodel,
	.deathmsg	= w_pipebomb_deathmsg,
	.aimanim	= w_pipebomb_aimanim,
	.hudpic		= w_pipebomb_hudpic,
	.isempty	= w_asscan_isempty
};