dmc/src/shared/w_lava_nailgun.qc

/*
 * Copyright (c) 2023 Marco Cawthorne <marco@icculus.org>
 *
 * Permission to use, copy, modify, and distribute this software for any
 * purpose with or without fee is hereby granted, provided that the above
 * copyright notice and this permission notice appear in all copies.
 *
 * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
 * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
 * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
 * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
 * WHATSOEVER RESULTING FROM LOSS OF MIND, USE, DATA OR PROFITS, WHETHER
 * IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING
 * OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
 */

/*QUAKED weapon_nailgun (0 0 1) (-16 -16 0) (16 16 32)
"model" "models/g_nail.mdl"

DEATHMATCH CLASSIC (1999) ENTITY

Nailgun

*/

enum
{
	NAILGUN_IDLE,
	NAILGUN_SHOOT,
};

void
w_lava_nailgun_precache(void)
{
#ifdef SERVER
	Sound_Precache("weapon_nailgun.shoot");
	precache_model("models/g_lnail.mdl");
#else
	precache_model("models/v_lnail.mdl");
	precache_model("models/p_lnail.mdl");
#endif
}

int
w_lava_nailgun_pickup(player pl, int new, int startammo)
{
#ifdef SERVER
	if (pl.ammo_lava_nails < MAX_A_NAILS) {
		pl.ammo_lava_nails = bound(0, pl.ammo_lava_nails + 30, MAX_A_NAILS);
	} else {
		if (!new)
			return (0);
	}
#endif
	return (1);
}

void
w_lava_nailgun_updateammo(player pl)
{
	Weapons_UpdateAmmo(pl, -1, pl.ammo_lava_nails, -1);
}

string
w_lava_nailgun_wmodel(void)
{
	return "models/g_lnail.mdl";
}

string
w_lava_nailgun_pmodel(player pl)
{
	return "models/p_lnail.mdl";
}

string
w_lava_nailgun_deathmsg(void)
{
	return "";
}

void
w_lava_nailgun_draw(player pl)
{
	Weapons_SetModel("models/v_lnail.mdl");
	Weapons_ViewAnimation(pl, NAILGUN_IDLE);
}

void
w_lava_nailgun_primary(player pl)
{
	if (pl.w_attack_next > 0.0)
		return;
	if (pl.ammo_lava_nails <= 0) {
		Weapons_SwitchBest(pl, 0);
		return;
	}

	pl.ammo_lava_nails--;

	/* Actual firing */
#ifdef CLIENT
#else
	#if 0
	{
		static void nail_touch(void) {
			if (trace_ent.iBleeds) {
				FX_Blood(trace_endpos, [1,0,0]);
			} else {
				FX_Impact(IMPACT_MELEE, trace_endpos, trace_plane_normal);
			}

			if (trace_ent.takedamage) {
				Damage_Apply(trace_ent, self.owner, Skill_GetValue("plr_nailgun", 9), WEAPON_NAILGUN, DMG_BLUNT);
			} else {
				makevectors(self.angles);
				DecalGroups_Place("Impact.BigShot", trace_endpos + (v_forward * -2));
			}

			remove(self);
		}

		entity nail = spawn();
		setmodel(nail, "models/lspike.mdl");
		vector velOffset = pl.velocity * input_timelength;
		setsize(nail, g_vec_null, g_vec_null);
		nail.movetype = MOVETYPE_FLYMISSILE;
		nail.solid = SOLID_BBOX;
		nail.touch = nail_touch;
		nail.owner = pl;
		Weapons_MakeVectors(pl);

		if (pl.ammo_lava_nails & 1) {
			setorigin(nail, velOffset + Weapons_GetCameraPos(pl) + (v_right * -2) + (v_up * -5));
			nail.velocity = v_forward * 1000 + (v_right * -2) + (v_up * -5);
		} else {
			setorigin(nail, velOffset + Weapons_GetCameraPos(pl) + (v_right * 2) + (v_up * -5));
			nail.velocity = v_forward * 1000 + (v_right * 2) + (v_up * -5);
		}
		nail.angles = vectoangles(nail.velocity);
	}
	#else
	vector startPos;
	Weapons_MakeVectors(pl);

	if (pl.ammo_lava_nails & 1)
		startPos = Weapons_GetCameraPos(pl) + (v_right * -2) + (v_up * -5);
	else
		startPos = Weapons_GetCameraPos(pl) + (v_right * 2) + (v_up * -5);

	entity oldself = self;
	NSProjectile rocket = spawn(NSProjectile);
	rocket.owner = pl;
	self = rocket;
	EntityDef_SpawnClassname("projectile_lnail");
	self = oldself;
	rocket.Launch(startPos, pl.v_angle, 0.0f, 0.0f, 0.0f);
	#endif

	if (pl.HasQuadDamage()) {
		Sound_Play(pl, CHAN_ITEM, "item_artifact_super_damage.attack");
	}

	Sound_Play(pl, CHAN_WEAPON, "weapon_nailgun.shoot");
#endif

	Weapons_ViewPunchAngle(pl, [-2,0,0]);
	Weapons_ViewAnimation(pl, NAILGUN_SHOOT);
	Animation_PlayerTop(pl, (pl.flags & FL_CROUCHING) ? ANIM_CR_SHOOTMP5 : ANIM_SHOOTMP5, 0.45f);

	pl.w_attack_next = 0.1f;
}

void
w_lava_nailgun_crosshair(player pl)
{
#ifdef CLIENT
	vector aicon_pos;

	HUD_DrawQuakeCrosshair();
	HUD_DrawAmmo2();

	aicon_pos = g_hudmins + [g_hudres[0] - 48, g_hudres[1] - 42];
	drawsubpic(
		aicon_pos,
		[24,24],
		g_hudngammo,
		[0, 0],
		[24/24, 24/24],
		g_hud_color,
		pSeatLocal->m_flAmmo2Alpha,
		DRAWFLAG_ADDITIVE
	);
#endif
}

float
w_lava_nailgun_aimanim(player pl)
{
	return pl.flags & FL_CROUCHING ? ANIM_CR_AIMMP5 : ANIM_AIMMP5;
}

int
w_lava_nailgun_isempty(player pl)
{
	if (pl.ammo_lava_nails <= 0)
		return 1;

	return 0;
}

void
w_lava_nailgun_hudpic(player pl, int selected, vector pos, float a)
{
#ifdef CLIENT
	vector hud_col;

	if (w_lava_nailgun_isempty(pl))
		hud_col = [1,0,0];
	else
		hud_col = g_hud_color;

	if (selected) {
		drawsubpic(pos, [170,45], g_hudng_spr, [0,0], [1,0.625], hud_col, a, DRAWFLAG_ADDITIVE);
	} else {
		drawsubpic(pos, [170,45], g_hudng_spr, [0,0], [1,0.625], hud_col, a, DRAWFLAG_ADDITIVE);
	}

	HUD_DrawAmmoBar(pos, pl.ammo_lava_nails, MAX_A_NAILS, a);
#endif
}

weapontype_t
w_lava_nailgun_type(player pl)
{
	return WPNTYPE_RANGED;
}

weapon_t w_lava_nailgun =
{
	.name		= "lava_nailgun",
	.id			= ITEM_LAVANAIL,
	.slot		= 3,
	.slot_pos	= 1,
	.weight		= 6,
	.draw		= w_lava_nailgun_draw,
	.holster	= __NULL__,
	.primary	= w_lava_nailgun_primary,
	.secondary	= __NULL__,
	.reload		= __NULL__,
	.release	= __NULL__,
	.postdraw	= w_lava_nailgun_crosshair,
	.precache	= w_lava_nailgun_precache,
	.pickup		= w_lava_nailgun_pickup,
	.updateammo	= w_lava_nailgun_updateammo,
	.wmodel		= w_lava_nailgun_wmodel,
	.pmodel		= w_lava_nailgun_pmodel,
	.deathmsg	= w_lava_nailgun_deathmsg,
	.aimanim	= w_lava_nailgun_aimanim,
	.isempty	= w_lava_nailgun_isempty,
	.type		= w_lava_nailgun_type,
	.hudpic		= w_lava_nailgun_hudpic
};